KeyboardRectangle.qml

/*
 * Copyright (C) 2012-2015 Canonical, Ltd.
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; version 3.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */
 
import QtQuick 2.4
 
Item {
    id: keyboardRect
 
    property bool active: true
 
    anchors.left: parent.left
    anchors.right: parent.right
    anchors.bottom: parent.bottom
    height: active && Qt.inputMethod.visible ? Qt.inputMethod.keyboardRectangle.height : 0
 
    states: [
        State {
            name: "hidden"
            when: keyboardRect.height === 0
        },
        State {
            name: "shown"
            when: keyboardRect.height === Qt.inputMethod.keyboardRectangle.height
        }
    ]
 
    function recursiveFindFocusedItem(parent) {
        if (parent.activeFocus) {
            return parent;
        }
 
        for (var i in parent.children) {
            var child = parent.children[i];
            if (child.activeFocus) {
                return child;
            }
 
            var item = recursiveFindFocusedItem(child);
 
            if (item != null) {
                return item;
            }
        }
 
        return null;
    }
 
    Connections {
        target: Qt.inputMethod
 
        onVisibleChanged: {
            if (!Qt.inputMethod.visible) {
                var focusedItem = recursiveFindFocusedItem(keyboardRect.parent);
                if (focusedItem != null) {
                    focusedItem.focus = false;
                }
            }
        }
    }
}